Adding a simple log in

[sconlinemarketing 0]

I know just about any method of keeping your bot secure can be hacked, so I am not looking for something complicated.

 

Is there a simple way to create a box that they need to input a code I give them to run the bot.  This is just for the honest people of course, because we all know if someone wants to give your software away they will find a way.

 

Thanks for the replies.

[LoWrIdErTJ - BotGuru 904]

have a membership or member login area of your  website.

Requiring they have account details.

 

 

use the prompt action to set variables in the onload command

 

then in there execute in hidden browser to login to your site.  and validate by checking for errors of failed login, or if it reached inner page with specific text on it, it was successful.

do with failed login or success as needed withint he software.

[sconlinemarketing 0]

I just bought Ubot this past Friday, so I am very new to all this.  I managed to create a Facebook messaging bot over the weekend to sell, so I need something to keep people from just handing it out.  I don't quite understand what you mean above.

 

Thanks

[LoWrIdErTJ - BotGuru 904]

add me on skype

add: emw-dgn

 

 

this is an example how to lock down the software to a wordpress login area

 

commented code to show what areas are what in the code

comment("License will only validate 1 time per session

License details will store to a license.txt file 

in same location as your bot .exe

and preload it from that location if it already exists

or save upon entering the correct license details

this DOES NOT monitor multiple IPs or PC use.

It only locks the bot to the login system.")

ui window("Software License Info") {

    ui text box("License Username", #license username)

    ui text box("License Password", #license password)

}

comment("place in the url to your wordpress login page below

This is the page with the username and password 

input area as default from wordpress")

Validate Login("http://yoursite.com/wp-login-url")

define Validate Login(#wordpress login url) {

    clear list(%license login)

    if($comparison(#license username, "=", "")) {

        then {

            add list to list(%license login, $list from file("{$special folder("Application")}\\license.txt"), "Delete", "Global")

            set(#license user, $list item(%license login, 0), "Global")

            set(#license pass, $list item(%license login, 1), "Global")

        }

        else {

            add item to list(%license login, #license username, "Delete", "Global")

            add item to list(%license login, #license password, "Delete", "Global")

            save to file("{$special folder("Application")}\\license.txt", %license login)

            set(#license user, #license username, "Global")

            set(#license pass, #license password, "Global")

        }

    }

    if($comparison(#license validated, "!=", 1)) {

        then {

            load html("<h1><font color=green><center><b><BR><BR>Validating License..</b></center></font></h1>")

            wait(3)

            in new browser {

                comment("you may if you ahve Dev version Ubot add a invisible

node here to hide this browser from showing what its doing")

                clear cookies

                navigate(#wordpress login url, "Wait")

                wait for element(<name="wp-submit">, "", "Appear")

                type text(<username field>, #license user, "Standard")

                type text(<password field>, #license pass, "Standard")

                change checkbox(<name="rememberme">, "Checked")

                click(<name="wp-submit">, "Left Click", "No")

                wait for browser event("Everything Loaded", "")

                wait(5)

                if($exists(<id="login_error">)) {

                    then {

                        alert("License Details Incorrect..")

                        stop script

                    }

                    else if($exists(<innertext="Dashboard">)) {

                        set(#license validated, 1, "Global")

                    }

                    else {

                        alert("License Details Incorrect..")

                        stop script

                    }

                }

            }

        }

        else {

        }

    }

}


 

}